Vous êtes sur la page 1sur 6

Lógica de Construção de Programas - Algoritmos

Algoritmo
É um texto contendo instruções que devem ser executadas em uma certa ordem. Através do
algoritmo, seguem-se normas executáveis, a fim de se obter o efeito desejado, o qual geralmente
consiste na obtenção de uma solução para um certo tipo de problema.
Exemplos de algoritmos:
 Instruções para uso de um determinado produto;
 Indicações de montagem de um determinado aparelho;
 Receitas de cozinha;
 Informação sobre o caminho para se chegar a determinado local (rodoviária, museu).
Na área de programação, um algoritmo nada mais é do que a descrição lógica e detalhada dos
comandos ou ordens a serem executadas pelo computador, dentro de um determinado programa. Os
algoritmos serão testados através de um programa chamado Portugol. (Programa em português).
Variáveis de Memória
É um espaço reservado na memória do computador, onde podem ser armazenadas determinadas
informações, sendo que, durante a execução do programa, o seu conteúdo pode variar.
Toda e qualquer variável de memória deve receber um nome, para que seja possível sua
identificação. Uma variável pode possuir qualquer nome, composto por letras e números, desde que
o primeiro caracter não seja um número. É importante lembrar que não é permitido a utilização de
espaços, acentuações ou símbolos especiais no nome da variável.
Tipos de Variáveis
De acordo com o seu conteúdo, as variáveis são classificadas nos seguintes tipos:
 Variável Inteiro : Pode armazenar somente números inteiros, os quais podem ser positivos (125), negativos
(-125) ou nulos (0). É importante lembrar que podemos fazer cálculos com o conteúdo das variáveis Inteiro.
Ex.: Nome da variável Conteúdo da variável
VALOR -5
TOTAL 583
SALDO 0
 Variável Real: Pode armazenar números inteiros ou números com decimal, os quais podem ser
positivos (10 ou 10.5) negativos (-10 ou -10.5) ou nulos (0). No Portugol, utilizamos o ponto
(.) como separador decimal. Como acontece com as variáveis Inteiro, também podemos fazer
cálculos com o conteúdo das variáveis Re al.
Ex.: Nome da variável Conteúdo da variável
DEBITO 354.89
ENTRADA 235
VALOR -50.58
NUMERO 0
 Variável Literal: Pode armazenar letras, números, espaços e qualquer tipo de símbolos, sendo
que, os números contidos neste tipo de variável não podem ser utilizados para cál culos.
Ex.: Nome da variável Conteúdo da variável
CONTRATO '001'
NOME 'ANDRÉ DA SILVA'
ENDERECO 'RUA GETÚLIO VARGAS, 222'
CIDADE 'CONCÓRDIA'
Obs.: O conteúdo de uma variável Literal sempre deve ser colocado entre aspas simples, para que
este, não seja interpretado como sendo o nome de uma variável.
Estrutura Geral (Simples) de um Algoritmo
Vimos anteriormente, que um algoritmo nada mais do que um Programa feito em Português, sendo
assim, também possui uma estrutura que deve ser seguida para que o mesmo funcione corretamente,
ou seja:
Algoritmo <Nome do Algoritmo>;
<[Declaração de Variáveis]>;
Inicio
<Comandos>;
Fim.
Todo e qualquer algoritmo deve sempre iniciar pela palavra Algoritmo, seguido por um nome
simbólico, o qual é dado ao algoritmo com a finalidade de diferencia-lo dos demais. Já, a
declaração de variáveis é utilizada para que possamos definir (criar) as variáveis de memória que
serão utilizadas pelo algoritmo.
O Inicio e Fim, são respectivamente as palavras reservadas para determinar o início e o fim
dos comandos que compõem um algoritmo, onde, o conjunto de comandos contidos no mesmo é executado
numa seqüência linear, de cima para baixo.

Comando: Atribuir ou Recebe ( <- )


Definição: O comando Recebe ( <- ) é utilizado para atribuir conteúdo a uma variável, a qual deve

1
Lógica de Construção de Programas - Algoritmos
ser declarada (criada) anteriormente, como mostra o exemplo abaixo.
Sintaxe:
Para declarar as variáveis
Var
< Nome da Variável > : < Tipo da Variável > ;
Para atribuir conteúdo a uma variável
< Nome da variável > <- < Conteúdo da Variável > ;
Exemplo:
Algoritmo Exemplo01;
VAR
Valor: Real;
Nota: Real;
Nome: Literal;
AnoAtual: Inteiro;
Inicio
Valor <- 350;
Nota <- 8.5;
Nome <- 'Carlos da Silva';
AnoAtual <- 1998;
Fim.
Operadores Aritméticos
Permitem que você realize cálculos, envolvendo números ou o conteúdo de variáveis.
 Adição..........: +
 Subtração.......: -
 Multiplicação. . .: *
 Divisão.........: /
Exemplo:
Algoritmo Exemplo02;
VAR
Valor1, Valor2, Soma: Inteiro;
Inicio
Valor1 <- 200;
Valor2 <- 255;
Soma <- Valor1 + Valor2;
Fim.
Função: Escreva ()
Definição: Utilizada para exibir determinada informação, podendo esta, ser uma mensagem qualquer
ou o conteúdo de uma variável.
Sintaxe para apresentar uma mensagem qualquer: Escreva <('Mensagem')>;
Sintaxe exibir o conteúdo de uma variável: Escreva <(Nome da Variável)>
OBS:
Caso desejamos exibir uma mensagem na tela, esta deve ser colocada entre aspas simples (' ') e se
a informação for o conteúdo de uma variável, basta especificar seu respectivo nome.
Exemplo:
Algoritmo Exemplo03;
Inicio
Escreva ('Brasil Sul Informática');
Escreva ('Cursos Profissionais');
Fim.
Algoritmo Exemplo04;
VAR
Valor1, Valor2, Soma: Inteiro;
Inicio
Valor1 <- 450;
Valor2 <- 550;
Soma <- Valor1 + Valor2;
Escreva (Valor1);
Escreva (Valor2);
Escreva ('A Soma Entre Os Dois Valores É: ', Soma);
Fim.
Função: Leia ()
Definição: Permite que o usuário altere o conteúdo das variáveis, ou seja, permite a digitação de
2
Lógica de Construção de Programas - Algoritmos
informações, as quais serão gravadas na variável indicada, como mostra a sintaxe:
Sintaxe: Leia <(Nome da Variável)>;
Onde:
(Nome da Variável) - Indica onde as informações digitadas pelo usuário serão gravadas.
Exemplo:
Algoritmo Exemplo05;
VAR
Cliente: Literal;
Quantidade: Inteiro;
ValorUnitario, ValorTotal: Real;
Inicio
Escreva ('Digite O Nome Do Cliente');
Leia (Cliente);
Escreva ('Digite a quantidade de produtos comprados');
Leia (Quantidade);
Escreva ('Digite o valor unitário do produto');
Leia (ValorUnitario);
ValorTotal <- Quantidade * ValorUnitario;
Escreva ('O valor total é: ', Valortotal);
Fim.
Algoritmo Exemplo06;
VAR
Nota1, Nota2, Media: real;
Inicio
Escreva ('Digite uma nota');
Leia (Nota1);
Escreva ('Digite outra nota');
Leia (Nota2);
Media <- (Nota1 + Nota2)/2;
Escreva ('Sua média é: ', Media);
Fim.
Seqüência Estruturada
Até então, os algoritmos criados contêm instruções, as quais são executadas em seqüência
linear, de cima para baixo. Já com a utilização da seqüência estruturada, teremos um conjunto de
instruções, que não obedecem a uma seqüência linear, ou seja, as instruções não são executadas
exatamente na mesma ordem em que foram escritas, abandonando assim o fluxo natural de execução
das instruções (de cima para baixo).
A seqüência estruturada é subdividida em Estrutura de Decisão e Estrutura de Repetição, nas
quais devemos especificar determinadas condições que deverão ser avaliadas, indicando assim se a
próxima seqüência de instruções deverá ou não ser executada. Para que possamos especificar essas
condições, utilizaremos os Operadores Relacionais, através dos quais podemos estabelecer relação
entre variáveis e os Operadores Lógicos, através dos quais podemos especificar mais do que uma
condição ao mesmo tempo.
Operadores Relacionais Operadores Lógicos
 Diferente ..........: < > E
 Igual ..............: =  OU
 Maior que ..........: >  NAO
 Menor que ..........: <
 Maior ou Igual que . : >=
 Menor ou Igual que . : <=

Exemplo:
Algoritmo Exemplo07;
VAR
Num1, Num2, Num3, Num4: Inteiro;
Inicio
Num1 <- 30;
Num2 <- 22;
Num3 <- 25;
Num4 <- 30;
Fim.

3
Lógica de Construção de Programas - Algoritmos
Estamos avaliando o conteúdo das variáveis criadas no exemplo anterior, através dos
operadores relacionais e operadores lógicos, veja:
Num1 > Num2 (Verdadeiro)
Num3 < Num2 (Falso)
Num2 <= Num4 (Verdadeiro)
Num1 >= Num4 (Verdadeiro)
(Num2 < Num1) E (Num1 < Num3) (Falso)
(Num1 > Num2) E (Num1 >= Num4) (Verdadeiro)
(Num2 > Num1) OU (Num4 = Num1) (Verdadeiro)
(Num1 <> Num2) OU (Num3 >= Num2) (Verdadeiro)
Estrutura de Decisão
É utilizada quando determinada ação a ser executada depende de uma condição, ou seja, é
avaliada esta condição e, baseando-se no resultado desta, executa-se ou não determinado comandos.
Podemos subdividir a Estrutura de Decisão em duas partes:
1. Decisão Simples - Consiste na avaliação de uma condição, caso esta resultar em Verdadeiro,
o próximo conjunto de comandos é executado, caso contrário, este é simplesmente ignorado,
continuando normalmente a execução dos próximos comandos da seqüência simples.
Comando: Se... Entao... FimSe;
Sintaxe: Se <Condição> Entao
<Comandos>;
FimSe;
Exemplo:
Algoritmo Exemplo08;
VAR
Cliente: Literal;
Saldo, Limite, Resultado: Real;
Inicio
Escreva ('Digite o nome do cliente');
Leia (Cliente);
Escreva ('Qual é o saldo do cliente?');
Leia (Saldo);
Escreva ('Qual o limite atual do cliente?');
Leia (Limite);
Resultado <- Saldo + Limite;
Se Resultado < 0 entao
Escreva ('Atenção! Seu saldo está estourado');
FimSe;
Escreva ('Seu saldo atual é: ', Resultado);
Fim.
2. Decisão Composta - Consiste na avaliação de uma determinada condição, sendo que, se esta
resultar em Verdadeiro, um determinado conjunto de comandos é executado e, se resultar em
Falso, outro conjunto de comandos é executado.
Comando: Se... Entao... Senao... FimSe;
Sintaxe: Se <Condição> Entao
<Comandos>;
Senao
<Comandos>;
FimSe;
Exemplo:
Algoritmo Exemplo09;
VAR
Nome: Literal;
AnoNasc, AnoAtual, Idade: Inteiro;
Inicio
Escreva ('Digite seu nome');
Leia (Nome);
Escreva ('Qual o ano do seu nascimento? ');
Leia (AnoNasc);
Escreva ('digite o ano atual');
Leia (AnoAtual);
Se AnoAtual > AnoNasc entao
Idade <- AnoAtual - AnoNasc;
Escreva ('Sua idade é: ', Idade);
Senao
Escreva ('Erro! Impossível calcular a idade. ');
FimSe;
Fim.

4
Lógica de Construção de Programas - Algoritmos
3. Múltipla Alternativa – Consiste na avaliação de um conjunto de condições, sendo que apenas
uma delas será Verdadeira e o conjunto de comandos que estiver especificado nesta condição
será executado. Mesmo sendo a primeira condição verdadeira o programa não deixa de testa
as demais.
Comando: Se... Entao... FimSe;
Sintaxe: Se <Condição> Entao
<Comandos>;
FimSe;
Se <Condição> Entao
<Comandos>;
FimSe;
Se <Condição> Entao
<Comandos>;
FimSe;
Exemplo:
Algoritmo Exemplo10;
VAR
Numero: Inteiro;
Inicio
Escreva ('Digite um número qualquer');
Leia (Numero);
Se Numero > 0 entao
Escreva ('O número digitado é Positivo');
FimSe;
Se Numero < 0 entao
Escreva ('O número digitado é Negativo');
FimSe;
Se Numero = 0 entao
Escreva ('O número digitado é Nulo');
FimSe;
Fim.
Estrutura de Repetição
É utilizada quando uma determinada seqüência de comandos que foram escritos apenas uma vez e
devem ser executados várias vezes. O que caracteriza esta estrutura é a criação de um laço, ou
seja, um bloco, que irá conter todas aquelas instruções as quais serão executados um determinado
número de vezes, sendo que, de acordo com o tipo de laço utilizado, o número de vezes poderá ser
um número fixo ou poderá variar, dependendo de uma certa condição que será especificada. É
importante lembrar que a estrutura de repetição trabalha com Contadores, os quais são variáveis
criadas para contar a quantia de vezes que a seqüência de comandos será executada.
1. Enquanto Faca - Consiste na repetição de uma seqüência de comandos enquanto uma
determinada condição permanecer verdadeira, ou seja, é especificada uma certa condição,
sendo que esta é testada toda vez que aquela seqüência de comandos é executada.
Funciona da seguinte maneira: quando o programa atinge o início do laço, a condição é
testada. Caso resulte em Verdadeiro, os comandos que estão no interior do laço são
executados até que se chegue ao final desse laço. Nesse ponto, o programa volta para o
início do laço e a condição é testada novamente. Caso resulte em Verdadeiro, os
comandos são novamente executados e todo o processo se repete. Caso resulte em Falso,
os comandos que estão dentro do laço não são executados e a execução do programa
continua normalmente com as próximas instruções.
Comando: Enquanto... Faca... FimEnquanto
Sintaxe: Enquanto <Condição> Faca
<Comandos>;
FimEnquanto;
Exemplo:
Algoritmo Exemplo10;
VAR
Numero, Cont, Resultado: Inteiro;
Inicio
Escreva ('Digite um número');
Leia (Numero);
Cont <- 1;
Enquanto Cont <= 10 faca
Resultado <- Numero * Contador;
Escreva (Resultado);
Cont <- Cont + 1;
FimEnquanto;
Fim.

5
Lógica de Construção de Programas - Algoritmos
2. Para Faca - Consiste na repetição de uma seqüência de comandos por uma determinada
quantidade de vezes, ou seja, é criada uma variável, sendo que esta servirá como um
contador, que irá controlar quantas vezes aquela seqüência de instruções deve ser
executada.
Funciona da seguinte maneira: é atribuído um valor inicial à variável e indicado também
o seu valor final. Quando o programa atinge o início do laço é analisado o valor da
variável contador. Caso seu valor ainda não tenha ultrapassado o valor final
especificado, os comandos serão executados até que se chegue ao final desse laço. Nesse
ponto, o programa volta para o início do laço e a variável tem o seu valor alterado, ou
seja, esta recebe um incremente de 1 no valor atual da variável. Caso o valor da
variável ainda não tenha ultrapassado o valor final, os comandos são novamente
executados e todo o processo se repete. Caso a variável já tenha ultrapassado o valor
final, os comandos que estão dentro do laço não são executados e a execução do programa
continua normalmente na instrução seguinte, após o fim do laço.
Comando: Para... Faca... FimPara
Sintaxe: Para <variável> <- <valor inicial> Ate <valor final> Faca
<Comandos>;
FimPara;
Exemplo:
Algoritmo Exemplo11;
VAR
Numero, Cont, Resultado: Inteiro;
Inicio
Escreva ('Digite um número');
Leia (Numero);
Para Cont <- 1 ate 10 faca
Resultado<- Numero * Cont;
Escreva (Resultado);
Fimpara;
Fim.

Vous aimerez peut-être aussi