Académique Documents
Professionnel Documents
Culture Documents
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 1/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Hola a todos, hoy os dejo una serie de ejercicios propuestos y resueltos sobre arreglos o
arrays en pseudocódigo.
Los ejercicios no tienen una única solución, el objetivo es que haga lo que pide y si se pide que
se haga de una forma especi ca hacerlo.
Esta vez, están hechos en PseInt, pero os recomiendo que los penséis un poco antes de
poneros a programar. Los indices de los arrays o arreglos que usaremos sera el
predeterminado por PseInt, es decir, que empezaran en 1. Puedes hacerlos como te
convengan
Aquí os dejo algunos posts anteriores para recordar algunos puntos por si lo necesitáis:
Variables y constantes.
Operadores.
Asignación.
Funciones internas.
Instrucciones de control.
Seguimiento.
Declaración.
Análisis de un problema.
Descarga de PSeInt.
Arreglos o arrays.
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 2/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
ATENCIÓN: si copias el código y te salta algún tipo de error, revisar el tipo de lenguaje que
usas. Puedes cambiarlo en Con gurar-Opciones del lenguaje-personalizado
1) Crea un array o arreglo unidimensional con un tamaño de 5, asignale los valores numéricos
manualmente (los que tu quieras) y muestralos por pantalla.
Esconder «
1 Proceso Ejercicio1
2
3 //Declaramos variables
4 Definir num como entero;
5 Definir TAMANIO como entero;
6 TAMANIO<‐5
7 //Definimos el array
8 Dimension num[TAMANIO]
9
10 //Asignamos valores
11 num[1]<‐1
12 num[2]<‐2
13 num[3]<‐3
14 num[4]<‐4
15 num[5]<‐5
16
17 //Recorremos el array y mostramos su contenido
18 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
19 escribir num[i]
20 Fin Para
21
22 FinProceso
2) Modi ca el ejercicio anterior para que insertes los valores numéricos con leer mediante
un bucle y los muestre por pantalla.
Esconder «
1 Proceso Ejercicio2
2
3 //Declaramos variables
4 Definir num como entero
5
6 Definir TAMANIO como entero;
7 TAMANIO<‐5;
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 3/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
7 TAMANIO<‐5;
8
9 //Definimos el array
10 Dimension num[TAMANIO]
11
12 //Introducimos valores
13 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
14 Escribir "Introduce un valor para la posición ",i
15 leer num[i]
16 Fin Para
17
18 //Recorremos el array y mostramos su contenido
19 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
20 escribir num[i]
21 FinPara
22
23 FinProceso
3) Crea un array o arreglo unidimensional con un tamaño de 10, inserta los valores
numéricos que desees de la manera que quieras y muestra por pantalla la media de valores
del array.
Esconder «
1 Proceso Ejercicio3
2
3 //Declaramos variables
4 Definir num como entero
5 Definir TAMANIO como entero
6 Definir suma Como Entero
7 TAMANIO<‐10
8
9 //Definimos el array
10 Dimension num[TAMANIO]
11
12 //Introducimos valores
13 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
14 Escribir "Introduce un valor para la posición ",i
15 leer num[i]
16 Fin Para
17
18 //Recorremos el array, sumando su contenido
19 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
20 suma<‐suma+num[i]
21 FinPara
22
23 FinProceso
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 4/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Anuncios Google
Ejercicios paso a Arreglos Arrays Java
4) Crea un array o arreglo unidimensional donde tu le indiques el tamaño por teclado y crear
una función que rellene el array o arreglo con los múltiplos de un numero pedido por teclado.
Por ejemplo, si de no un array de tamaño 5 y eligo un 3 en la función, el array contendrá 3, 6,
9, 12, 15. Muestralos por pantalla usando otra función distinta.
Esconder «
1 SubProceso asignaValores ( num, TAMANIO, num_multiplo )
2
3 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
4 num[i]<‐num_multiplo*i
5 Fin Para
6 Fin SubProceso
7
8 SubProceso mostrarArray ( num, TAMANIO )
9 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
10 escribir num[i]
11 Fin Para
12 Fin SubProceso
13
14 Proceso Ejercicio4
15
16 //La creacion de subprocesos es totalmente opcional
17
18 //Declaramos variables
19 Definir num como entero
20 Definir TAMANIO como entero
21 Definir suma Como Entero
22 definir num_multiplo como entero
23
24 //Definimos el tamaño del array por teclado
25 escribir "Introduce el tamaño del array"
26 leer TAMANIO
27
28 //Definimos el array
29 Dimension num[TAMANIO]
30
31 //Definimos el numero con el que rellenaremos el array con sus multiplos
32 escribir "Introduce el numero con el que rellenar"
33 leer num_multiplo
34
35 //invocamos a las funciones
36 asignaValores(num, TAMANIO, num_multiplo)
37 mostrarArray(num, TAMANIO)
38
39 FinProceso
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 5/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
5) Crea dos arrays o arreglos unidimensionales que tengan el mismo tamaño (lo pedirá por
teclado), en uno de ellos almacenaras nombres de personas como cadenas, en el otro array o
arreglo ira almacenando la longitud de los nombres, para ello puedes usar la función
LONGITUD(cadena) que viene en PseInt. Muestra por pantalla el nombre y la longitud que
tiene. Puedes usar funciones si lo deseas.
Esconder «
1 SubProceso mostrarArrays ( longitud_nombres, nombres, TAMANIO )
2
3 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
4 escribir "La longitud del nombre ",nombres[i]," es de ",longitud_nom
5 Fin Para
6
7 Fin SubProceso
8
9 Proceso Ejercicio5
10
11 //Declaramos variables
12 Definir longitud_nombres como entero
13 Definir nombres como cadena
14 Definir TAMANIO como entero
15
16 //Definimos el tamaño del array por teclado
17 escribir "Introduce el tamaño de los arrays"
18 leer TAMANIO
19
20 //Definimos el array
21 Dimension longitud_nombres[TAMANIO]
22 Dimension nombres[TAMANIO]
23
24 //Introducimos los nombres y la longitud de los mismos
25 Para i<‐1 Hasta TAMANIO Con Paso 1 Hacer
26 escribir "Introduce un nombre para la posicion ",i
27 leer nombres[i]
28 longitud_nombres[i]<‐Longitud(nombres[i])
29 Fin Para
30
31 //Invocamos la función
32 mostrarArrays(longitud_nombres, nombres, TAMANIO)
33
34 FinProceso
6) Haz lo mismo que el ejercicio anterior pero con un arreglo o array multidimensional. Ten
en cuenta que no podemos tener una columna con cadena y otra con números, así que usa la
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 6/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Esconder «
1 SubProceso mostrarArrays ( nombres, FILAS )
2 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
3 //Usamos un bucle ya que seria mas complicado(no es imposible)
4 //mostrar dos valores en una misma instruccion
5 escribir "La longitud del nombre ",nombres[i,1]," es de ",nombres[i,
6 Fin Para
7 Fin SubProceso
8
9 Proceso Ejercicio6
10
11 //Declaramos variables
12 Definir longitud_nombres como entero
13 Definir nombres como cadena
14 Definir FILAS como entero
15 definir num_nombre como cadena
16
17 //Definimos las filas del array por teclado
18 escribir "Introduce las filas del array multidimensional"
19 leer FILAS
20
21 //Definimos el array
22 Dimension nombres[FILAS, 2]
23
24 //Introducimos los nombres y la longitud de los mismos
25 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
26 escribir "Introduce un nombre en la fila ",i
27 leer nombres[i, 1]
28 num_nombre<‐convertiratexto(Longitud(nombres[i, 1]))
29 nombres[i, 2]<‐num_nombre
30 Fin Para
31
32 //Invocamos la función
33 mostrarArrays( nombres, FILAS)
34
35 FinProceso
7) Crea un arreglo o array multidimensional con un tamaño que nosotros le indiquemos por
teclado (puede ser 6×4, 7×2, etc.), recorre el array o arreglo e introduce número aleatorios
(función azar(x) donde x es el limite donde generara), crea una función llamada rellenaArray.
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 7/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Por último, muestralos por pantalla tal como quedarían en el array o arreglo, es decir, si el
array es de 5×5 tendremos que hace que cada 5 números baje una línea, por ejemplo:
52684
54321
98742
98752
23542
Esconder «
1 SubProceso rellenaArray ( num, FILAS, COLUMNAS )
2
3 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
4 Para j<‐1 Hasta COLUMNAS Con Paso 1 Hacer
5 //Genera numeros entre 0 y 9
6 num[i,j]<‐azar(10)
7 Fin Para
8 Fin Para
9 Fin SubProceso
10
11 SubProceso mostrarArray ( num, FILAS, COLUMNAS)
12 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
13 Para j<‐1 Hasta COLUMNAS Con Paso 1 Hacer
14 escribir num[i,j]," " Sin Saltar
15 Fin Para
16 //Salto de linea
17 escribir ""
18 Fin Para
19 Fin SubProceso
20
21 Proceso Ejercicio7
22
23 //Declaramos variables
24 Definir num como entero
25 Definir FILAS como entero
26 Definir COLUMNAS Como Entero
27
28 //Definimos las filas y columnas del array por teclado
29 escribir "Introduce las filas del array"
30 leer FILAS
31
32 escribir "Introduce las columnas del array"
33 leer COLUMNAS
34
35 //Definimos el array
36 Dimension num[FILAS, COLUMNAS]
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 8/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
36 Dimension num[FILAS, COLUMNAS]
37
38 //Invocamos la función
39 rellenaArray(num, FILAS, COLUMNAS)
40 mostrarArray( num, FILAS, COLUMNAS)
41
42 FinProceso
8) Crea un arreglo o array multidimanesional que contenga 3 columnas y las las que tu
quieras, las dos primeras columnas tendrán números y en la 3 columna sera el resultado de
sumar el número de la primera y segunda columna. Muestra el array o arreglo de la siguiente
forma:
3+5=8
4+4=7
Esconder «
1 SubProceso mostrarArray ( num, FILAS )
2
3 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
4 escribir num[i,1]," + ",num[i,2]," = ",num[i, 3]
5 Fin Para
6 Fin SubProceso
7
8 Proceso Ejercicio8
9
10 //Declaramos variables
11 Definir num como entero
12 Definir FILAS como entero
13 Definir COLUMNAS Como Entero
14
15 //Definimos las fila del array por teclado, las columnas
16 //ya sabemos que siempre seran 3
17 escribir "Introduce las filas del array multidimensional"
18 leer FILAS
19 COLUMNAS<‐3
20
21 //Definimos el array
22 Dimension num[FILAS, COLUMNAS]
23
24 //Introducimos los nombres y la longitud de los mismos
25
26 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
27 Para j<‐1 Hasta COLUMNAS Con Paso 1 Hacer
28 //Cuando j llegue a 3 (donde debemos sumar), sumara los valores
29 //esto permite que nos ahorremos despues un bucle
30 si (j=COLUMNAS) Entonces
31 num[i,j]<‐num[i,1]+num[i,2]
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 9/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
31 num[i,j]<‐num[i,1]+num[i,2]
32 Sino
33 Escribir "Introduce un numero para la FILA ",i," COLUMNA ",j
34 leer num[i,j]
35 FinSi
36 Fin Para
37 Fin Para
38
39 //Invocamos la función
40 mostrarArray( num, FILAS)
41
42 FinProceso
Anuncios Google
2 ejercicios 2 Ejemplo ejercicio PHP arrays
9) Crea un arreglo o array multidimensional con un tamaño que de niremos nosotros por
teclado, contendrá números aleatorios usando la función anterior y crearemos un array o
arreglo unidimensional donde se copiaran los números que contiene el array
multidimensional. Piensa que tamaño debe tener el array o arreglo unimensional.
Esconder «
1 SubProceso copiaArray ( num_multidimensional,num_unidimensional, FILAS, COLU
2
3 //Esta variable la usaremos para controlar
4 definir saltador como entero
5 saltador<‐0
6
7 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
8 Para j<‐1 Hasta COLUMNAS Con Paso 1 Hacer
9 num_unidimensional[j+saltador]<‐num_multidimensional[i,j]
10 Fin Para
11 saltador<‐saltador+COLUMNAS
12 Fin Para
13
14 Fin SubProceso
15
16 SubProceso rellenaArray ( num, FILAS, COLUMNAS )
17
18 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
19 Para j<‐1 Hasta COLUMNAS Con Paso 1 Hacer
20 //Genera numeros entre 0 y 9
21 num[i,j]<‐azar(10)
22 Fin Para
23 Fin Para
24 Fin SubProceso
25
26 SubProceso mostrarArray ( num_unidimensional, FILAS, COLUMNAS)
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 10/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
26 SubProceso mostrarArray ( num_unidimensional, FILAS, COLUMNAS)
27
28 Para i<‐1 Hasta FILAS*COLUMNAS Con Paso 1 Hacer
29 escribir num_unidimensional[i]
30 Fin Para
31
32 Fin SubProceso
33
34 Proceso Ejercicio9
35
36 //Declaramos variables
37 Definir num_multidimensional como entero;
38 Definir num_unidimensional como entero;
39 Definir FILAS como entero
40 Definir COLUMNAS Como Entero
41
42 //Definimos las filas y columnas del array por teclado
43 escribir "Introduce las filas del array"
44 leer FILAS
45 escribir "Introduce las columnas del array"
46 leer COLUMNAS
47
48 //Definimos el array
49 Dimension num_multidimensional[FILAS, COLUMNAS]
50 Dimension num_unidimensional[FILAS*COLUMNAS]
51
52 //Invocamos laa funciones
53 rellenaArray(num_multidimensional, FILAS, COLUMNAS)
54 copiaArray(num_multidimensional,num_unidimensional, FILAS, COLUMNAS)
55 mostrarArray( num_unidimensional, FILAS, COLUMNAS)
56
57 FinProceso
Anuncios Google
Pro crear Pro tabla PHP pro
10) Crea un array o arreglo multidimensional que contenga la tabla de multiplicar del 1 al 9
(10 las y 10 columnas). La primera la y la columna debe contener estos números. Algo así:
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 11/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
El resto de números deberemos calcularlo, usando los numeros que disponemos, es decir, en
la primera la de 0, calculara 1*1, 1*2, 1*3, etc. usando las posiciones del array o arreglo. Así
debe quedar al nal:
Esconder «
1 SubProceso calculaTabla ( tabla_multiplicar, FILAS, COLUMNAS )
2
3 Para i<‐2 Hasta FILAS Con Paso 1 Hacer
4 Para j<‐2 Hasta COLUMNAS Con Paso 1 Hacer
5 //Empezamos desde la posicion 2,2
6 //Lo único que varia es la fila o la columna en cada caso
7 tabla_multiplicar[i,j]<‐tabla_multiplicar[i,1]*tabla_multiplicar
8 Fin Para
9 Fin Para
10
11 Fin SubProceso
12
13 SubProceso rellenaColumnasPrinc ( tabla_multiplicar, FILAS)
14
15 definir contador como entero
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 12/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
15 definir contador como entero
16 contador<‐0
17
18 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
19 tabla_multiplicar[1,i]<‐contador
20 tabla_multiplicar[i,1]<‐contador
21 contador<‐contador+1
22 Fin Para
23
24 Fin SubProceso
25
26 SubProceso mostrarArray ( tabla_multiplicar, FILAS, COLUMNAS)
27
28 Para i<‐1 Hasta FILAS Con Paso 1 Hacer
29 Para j<‐1 Hasta COLUMNAS Con Paso 1 Hacer
30 escribir tabla_multiplicar[i,j]," " Sin Saltar
31 Fin Para
32 //Salto de linea
33 escribir ""
34 Fin Para
35
36 Fin SubProceso
37
38 Proceso Ejercicio10
39
40 //Definimos las variables
41 definir FILAS como entero
42 definir COLUMNAS como entero
43 FILAS<‐10
44 COLUMNAS<‐10
45 dimension tabla_multiplicar[FILAS,COLUMNAS]
46
47 //Funciones
48 rellenaColumnasPrinc(tabla_multiplicar, FILAS)
49 calculaTabla(tabla_multiplicar, FILAS, COLUMNAS )
50 mostrarArray(tabla_multiplicar, FILAS, COLUMNAS)
51
52 FinProceso
Espero que os sea de ayuda. Si teneis dudas, preguntad. Estamos para ayudarte.
resueltos soluciones
53 Comentarios
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 13/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 14/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Reset CSS
09/03/2013
53 COMMENTS
DIEGO PALACIOS
19/01/2014
hola me podrian ayudar con un ejercicio de arreglo que no me sale por nada del
mundo
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 15/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Pikao
19/01/2014
krurk
23/01/2014
Léxico
Lmax= 5;
I:entero[1.lmax];
Long:entero[1, lmax];
T: Tipo Tabla[1,Lmax] de entero >= 0;
Algoritmo
: Long<–5;
T1<–1;
T2<–2;
T3<–3;
T4<–4;
T5<–5;
i Recorriendo [1, Long] Hacer
escribir( Ti);
Fin_Recorriendo;
Fin
Joan Sebastian
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 16/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Joan Sebastian
15/03/2014
me pueden hacer el de cajero con los billetes de $500,$200,$100 y $50 que solo
agarre esos para retirar el dinero
Pikao
19/03/2014
susy
29/04/2014
Una ayuda por favor tengo tres ejercicios con vectores ayedenme auquesea con
uno
1.- Sea un torneo hipico en el cual se registran 10 carreras del torneo como sigue:
numero de carrera, nombre del jockey, nombre del caballo, distancia que recorre,
tiempo registrado.
Además se cuenta con la información de los caballos: Nombre del caballo,peso,
edad, raza o procedencia.
Nota: los caballos no deben sobrepasar los 7 años tampoco debe haber nombre
duplicado del caballo.
En el mencionado torneo se van a registrar los 2 primeros caballos ganadores de
cada una de las carreras, para así poder premiar al caballo de mayor nùmero de
carreras ganadas. se le pide lo siguiente:
a) Crear las estructuras de datos adecuadas para el tratamiento de esta
información
b)Registrar un nuevo caballo que mantenga el orden descendente de edad.
c)Mostrar los caballos ganadores con su nombre del primer y segundo lugar de
cada una de las carreras.
d)Mostrar el nombre del caballo que a obtenido el mayor numero de carreras
ganadas
e)Mostrar el nombre del Jockey que ah obtenido el mayor número de carreras
ganadas.
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 17/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
Pikao
30/04/2014
Te respondo en un correo.
Saludos
javier
12/06/2014
Proceso sin_titulo
//Crear un algoritmo que Ingrese 7 números en un arreglo. Luego almacenarlos en
otro vector en orden inverso al vector original e imprimir
//el vector original y el inverso.
Fin Para
Escribir "Numeros ingresados en el primer vector";
Para i<-1 Hasta 10 Hacer
Escribir num(i);
Fin Para
escribir "- – – – – – – – – – ";
Escribir "Numeros ingresados en el Segundo vector";
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 18/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
FinProceso
Miguel Navarrete
27/06/2014
Caso 1:
Realizar un algoritmo que permita llenar un arreglo de largo N (validar que el valor
mínimo de N sea 3) que contenga las temperaturas de la ciudad de Valdivia en
grados Celcius. El arreglo se debe llenar en forma aleatoria en un rango entre -20°
y 40°, y además se solicita mostrar el promedio de temperaturas sobre 0°. Si no
hubo temperaturas sobre 0° mostrar el mensaje adecuado.
Caso 2
Realizar un algoritmo que permita llenar un arreglo de largo N con números
enteros positivos y validar que el valor de N y los elementos sean positivos. Luego
modi car los elementos del arreglo de la siguiente forma:
Si el elemento se encuentra en posición índice impar y tiene 2 dígitos, es aumentar
el valor de la decena de este. Mostrar el valor modi cado. (WTF)
-Después no dijo nada más de este caso-
Caso 3:
Un frigorí co de carnes de cordero ubicado en el centro de la ciudad de Punta
Arenas necesita computarizar las medidas de los corderos almacenados allí. Por
cada cordero se deben almacenar las siguientes variables:
– Número de serie: Cadena de caracteres
– Edad: Aleatoria en un rango entre 1 y 10
– Sexo: Si es macho (M) o hembra (H)
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 19/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
– Peso: En kilos
El frigorí co tiene una capacidad para recibir como máximo 100 corderos. Debe
realizar un algoritmo que permita ingresar dicha información en arreglos
paralelos y validar la información.
Almacenar en un nuevo arreglo los números de series de todos los corderos
hembras obesas (peso>40kg) y mostrar el arreglo con los números de serie. En
caso que no tuviera hembras obesas mostrar el mensaje correspondiente.
Pikao
29/06/2014
Hola,
Un saludo
DEJA UN COMENTARIO
Comentar*
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 20/21
16/5/2017 Ejercicios propuestos y resueltos arreglos o arrays en pseudocódigo | Disco Duro de Roer
PUBLICAR COMENTARIO
DONACIONES
Correo Electrónico *
¡SUSCRÍBETE!
https://www.discoduroderoer.es/ejerciciospropuestosyresueltosarreglosoarraysenpseudocodigo/ 21/21