NF04 – Pratique des EF avec ANSYS

Benjamin Hagège, Mabrouk Ben Tahar

Département Génie Mécanique 1
NF04 – UTC
Plan du cours (2 CM – 3 TD)

0°) Présentation générale d’ANSYS

I°) TD1 : plaque en conduction thermique

II°) TD2 : poutre en traction et flexion

III°) TD3 : barre en thermoélectricité

BONUS : Macro VBA d’import sous Powerpoint

2
NF04 – UTC
0°) Présentation générale d’ANSYS

3
NF04 – UTC
ANSYS, code n°1 mondial

4
NF04 – UTC
ANSYS, code n°1 mondial
Entreprises en France
-ALSTOM : tout ce qui est vibratoire
-AREVA : solution unique mondiale, du coup EdF aussi pour l'EPR
-EADS-ASTRIUM : impact sur les satellites
-SAFRAN : montée en puissance de Workbench, perte de vitesse d'Abaqus
-Certains centres ST-GOBAIN : impact sur les parebrises
-ARCELOR : pour LS-DYNA (distribué par ANSYS et inclu dans le code)
-VINCI, BOUYGUES CONSTRUCTION : notamment pour le projet à la Défense de
la nouvelle tour de 260m de haut
-VEOLIA
-SUEZ
-DCN
-DGA
-ALKAN (missiles)
-THALES
-SDBM (Monaco)
-ITER, CERN et bientôt le CEA
-Renault Sport F1

5
NF04 – UTC
ANSYS, code n°1 mondial

6
NF04 – UTC
Travailler avec ANSYS
Ouverture d’ANSYS CLASSIC (Mechanical APDL)
-Ouvrir le launcher
-Définir sa licence (Ansys Academic Introductory) et son répertoire de travail

Règles de base
-Réserver sur le HD un espace, permanent, pour la sauvegarde des fichiers (NF04-
TD1) et un espace, temporaire, pour le calcul (0Calculs)
-8 caractères pour un nom, pas d’espaces, pas d’accents
-ANSYS ne fait pas de différences entre majuscules et miniscules : E=e !

Méthodologie de mise en oeuvre

-Cliquer dans le Graphic User Interface sur une fonction
-Ouvrir le Session Editor pour construire son script APDL (dans un fichier .dat)

Structurer son job

-Paramètres + définition de la session
-Mise en donnée EF : type d’EF, real d’EF, matériaux, CAO, maillage
-Analyse : CL (T, U, ROT, V…), chargements (Q, F, M, I…), type de calcul, sorties
-Post-traitement : le plus difficile car dépend du problème ! Des iso-contours, des
champs de tenseur et des bilans textuels 7
NF04 – UTC
Travailler avec ANSYS
Mauvaise approche des EF
-Vouloir cliquer interactivement pour tout faire et ignorer le prompt (mode du
click’n’go)
-Refuser d’admettre que faire des éléments finis, c’est avant tout coder un job

Bonne approche des EF

-Coder ses jobs à l’ancienne avec un authentique préprocesseur, à savoir un
éditeur de texte performant (EditPlus, UltraEdit, PSPad…)
-Ne se servir du GUI que pour définir ses vues

Apprendre à scripter l’APDL

-Le .log contient tout ce qui exécuté (clics ou commandes tapées dans le prompt)
-Pour apprendre : cliquer pour effectuer l’action désirée dans le GUI, ouvrir le .log
(ou le session editor), copier la partie APDL correspondante et la stocker dans ses
tablettes pour la réutiliser
-Se servir de l’aide en tapant : help, nom2commande

8
NF04 – UTC
Organisation du GUI – 1
Modules d’ANSYS CLASSIC pour NF04
-/PREP7 : pré-processeur, /SOLU : CL+Chargements, analyse, /POST1 : post-
processeur

9
NF04 – UTC
Organisation du GUI – 2
Output Window et Pan/Zoom/Rotate
-Output Window : contrôle des commandes effectuées et affichage des
commentaires et résultats textuels (bilans)

10
NF04 – UTC
Help
Aide d’ANSYS sur la commande ou l’élément xxxx
-Dans le prompt taper : help,xxxx
-L’aide comporte de nombreux exemples de références : Verification Manual

Exemples de vérification
-VM1 : Statically Indeterminate Reaction Force Analysis (S. Timoshenko, Strength
of Material, Part I, Elementary Theory and Problems, 3rd Edition, D. Van Nostrand
Co., Inc., New York, NY, 1955, pg. 26, problem 10) :

-help,1 :
11
NF04 – UTC
vm1.dat en détail
/COM,ANSYS MEDIA REL. 11.0 (10/27/2006) REF. VERIF. MANUAL: REL. 11.0 /VERIFY,VM1
/PREP7
/TITLE, VM1, STATICALLY INDETERMINATE REACTION FORCE ANALYSIS …
ET,1,LINK1 ! TYPE D’ELEMENT NUMEROTE 1
R,1,1 ! CROSS SECTIONAL AREA (ARBITRARY) = 1
MP,EX,1,30E6 ! MATERIAU DE MODULE D’YOUNG 30E6 (psi)
N,1 ! NŒUD 1 EN (0,0)
N,2,,4 ! NŒUD 2 EN (0,4)
N,3,,7 ! NŒUD 3 EN (0,7)
N,4,,10 ! NŒUD 4 EN (0,10)
E,1,2 ! DEFINE ELEMENTS (ENTRE LES NŒUDS 1 ET 2)
EGEN,3,1,1 ! GENERER 3 ELEMENTS A PARTIR DE L’ELEMENT 1 PAR INC. DE 1
D,1,ALL,,,4,3 ! BOUNDARY CONDITIONS AND LOADING (D=DISPLACEMENT=qinc)
F,2,FY,-500 ! APPLIQUER UNE FORCE AU NŒUD 2 SELON Y DE -500 (lb) (F=FORCE=Fext)
F,3,FY,-1000 ! APPLIQUER UNE FORCE AU NŒUD 3 SELON Y DE -1000 (lb)
/SOLU
ANTYPE,STATIC ! STATIC ANALYSIS
OUTPR,BASIC,1 ! SORTIR LES GRANDEURS BASIQUES
OUTPR,NLOAD,1 ! SORTIR LES CHARGEMENTS NODAUX
SOLVE ! LANCER LE CALCUL
/POST1
NSEL,S,LOC,Y,10 ! SELECTION SUR LE PLAN Y=10 DES NOEUDS
FSUM ! SOMMER LES EFFORTS ET MOMENTS SELON X, Y, Z
*GET,REAC_1,FSUM,,ITEM,FY ! ATTRAPER LA VALEUR DE LA SOMMATION PRECEDENTE
NSEL,S,LOC,Y,0
FSUM
*GET,REAC_2,FSUM,,ITEM,FY 12
NF04 – UTC
vm1.dat en détail - amélioration
Post-traitement
-le post-traitement répond uniquement à la question posée : quelles forces de
réactions pour ce problème hyperstatique ?
-Obtenir les forces de réactions dans un fichier rapport.post :
/POST1
NSEL,S,LOC,Y,10
FSUM
*GET,REAC_1,FSUM,,ITEM,FY
NSEL,S,LOC,Y,0
FSUM
*GET,REAC_2,FSUM,,ITEM,FY

/OUTPUT,rapport,post
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !!!! CALCUL DES REACTIONS !!!!!!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM REACTION HAUT (lb) : %REAC_1%
/COM REACTION BAS (lb) : %REAC_2%
/OUTPUT

13
NF04 – UTC
Calcul en pratique
2 modes d’utilisation
-Session intéractive : mise en donnée, vérification, petit calcul. On travaille par
copier/coller du .dat vers le prompt d’ANSYS
-Batch : pas d’interface graphique, gros calculs validés à la suite. On exécute un
programme préparé

Comment batcher un job ANSYS ?

-2 fichiers sont nécessaires sous Windows : !EXEC.bat et Liste.cmd
-!EXEC.bat : fichier à exécuter qui va appeler le .cmd. Il contient :
@echo off
set ANSYS130_PRODUCT=aa_t_a (anciennement aa_t_i)
set ANS_CONSEC=YES
call “Z:\0Calculs\Liste.cmd“

- Liste.cmd : fichier qui contient la liste des jobs et l’emplacement de l’exécutable

ANSYS :
CD Z:\0Calculs\
"C:\Program Files\Ansys Inc\v130\ANSYS\bin\Intel\ansys130" -b -i 0NF04_ANSYS-1.dat
-o 0NF04_ANSYS-1.out
"C:\Program Files\Ansys Inc\v130\ANSYS\bin\Intel\ansys130" -b -i 0NF04_ANSYS-2.dat
-o 0NF04_ANSYS-2.out 14
NF04 – UTC
Calcul en pratique
Savoir s’organiser
-Existence de 3 répertoires de travail sur Z:/

-Répertoire de sauvegarde : PERMANENT pour sauvegarde des jobs

-Répertoire de travail : TEMPORAIRE pour édition des jobs ou run intéractif
-Répertoire de calcul : TEMPORAIRE pour exécution des jobs en batch 15
NF04 – UTC
I°) Exemple de TD : plaque en conduction
thermique

16
NF04 – UTC
Physique du problème

Thermique
-Type de transferts : conduction, convection (libre/forcée), rayonnement ?
-Grandeurs à analyser : T (°C), q (W/m²), F (W)

=> graphiques : iso-contours, champs de vecteur

=> feuille de calcul : bilan des flux

17
NF04 – UTC
Job : paramètres – 1
!! SYSTEME mm, °C, mW
!*******************************************************************************
TA=44.51151 !TEMP ANALYTIQUE POINT A
TB=36.40567 !TEMP ANALYTIQUE POINT B
!!PROBLEME
a=1000. !DIMENSION X PLAQUE
b=500. !DIMENSION y PLAQUE
k=1. !CONDUCTIVITE THERMIQUE BETON
!!
!!
!!MAILLAGE !**
!!
!!
!!POST
NOMJOB=‘NF04_ANSYS-1’ !NOM DU JOB (CHAINE DE CARACTERES) !**
SFACTOR=10 !FACTEUR DE ZOOM POUR LES VECTEURS

Remarque : en violet et avec !** sont indiqués les endroits où il faudra modifier le
code en TD afin de réaliser l’ensemble des calculs et des post-traitements
automatiquement.
18
NF04 – UTC
Job : mise en donnée – 2
!*******************************************************************************
/NOPR !PAS DE COMMENTAIRES DANS L'OUTPUT WINDOW
/TITLE,%NOMJOB% !TITRE SUR LA FENETRE D'AFFICHAGE
/FILENAME,%NOMJOB% !NOM DES FICHIERS GENERES
!*
!*
!*
!*
!*
!*
!*******************************************************************************
/PREP7 !ENTREE DANS LE PREPROCESSEUR
!*
ET,1,PLANE55 !TYPE D'EF AVEC L'ORDRE, ICI BILINEAIRE !**
!*
MP,KXX,1,k !MATERIAU
!*
RECTNG,0,a/2.,0,b, !CAO
!*
!*
!*
!*MAILLAGE
MSHAPE,0,2D !MeshSHAPE, ici QUADRANGLE !**
MSHKEY,1 !MAILLAGE REGLE
AESIZE,ALL,50, !AreaElementSIZE=50mm SUR TOUTES LES SURFACES !**
AMESH,ALL !AreaMESH SUR TOUTES LES SURFACES SELECTIONNEES
19
NF04 – UTC
Job : CL, chargement et résolution – 3
!*******************************************************************************
/SOL !ENTREE DANS LE SOLVEUR
!*
ANTYPE,0 !ANALYSE REGIME PERMANENT 0=STATIC
!*
nsel,,loc,X !SELEC BORD X-
nsel,a,loc,Y,b !RAJOUTER BORD Y+
nplot !AFFICHER LES NOEUDS
D,ALL,TEMP,0. !CL SUR TOUS LES NOEUDS SELECTIONNE T=0°C
!*
nsel,,loc,Y !SELEC BORD Y-
nplot
D,ALL,TEMP,100.
!*
allsel !TOUT SELECTIONNER
solve !LANCER LE CALCUL SUR LA SELECTION ACTIVE

20
NF04 – UTC
Job : post-traitement graphique – 4
/POST1 !ENTREE DANS LE POSTPROCESSEUR
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Inverser la video!
/RGB,INDEX,100,100,100, 0
/RGB,INDEX, 80, 80, 80,13
/RGB,INDEX, 60, 60, 60,14
/RGB,INDEX, 0, 0, 0,15
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/SHOW,PNG,,0 !DEBUT CAPTURES D'ECRAN
/pbc,RFORCE,,1 !AFFICHER LES FORCES DE REACTION
Eplot !AFFICHER LES ELEMENTS DE LA SELEC. ACTIVE
/pbc,RFORCE,,0 !NE PAS AFFICHER LES FORCES DE REACTION
/CVAL,ALL,20,30,36.40567,40,44.51151,60,80,100 !CODE DE COULEUR
plns,temp !CHAMP DE TEMPERATURE
/CVAL !RESET DU CODE DE COULEUR
ples,tf,sum !FLUX DE CONDUCTION ELEM ISOCONTOURS
plns,tf,sum !FLUX DE CONDUCTION NODAL ISOCONTOURS
!
/VSCALE,1,SFACTOR,0 !FACTEUR DE ZOOM DES VECTEURS
plvect,tf,,,,VECT,ELEM,ON !FLUX DE CONDUCTION CHAMP DE TENSEUR
/SHOW,CLOSE !FIN CAPTURES D'ECRAN
!
!
/SYS,MKDIR 1RESULTATS !CREER LE REPERTOIRE 1RESULTATS
/SYS,MOVE *.PNG 1RESULTATS/ !Y DEPLACER TOUTES LES CAPTURES D’ECRAN

21
NF04 – UTC
Job : post-traitement des bilans – 5.1
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! DONNES MODELE !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ALLSEL
*GET, NN, NODE, 0, COUNT !ATTRAPER LE NOMBRE DE NOEUDS
*GET, NE, ELEM, 0, COUNT !ATTRAPER LE NOMBRE D'ELEMENTS
!
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! TEMPERATURES CIBLES !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
LabNA=NODE(a/2,b/2,0.) !ATTRAPER LE LABEL DU NOEUD EN A
LabNB=NODE(a/4,b/2,0.) !ATTRAPER LE LABEL DU NOEUD EN B
*GET, TAMEF, NODE, LabNA, TEMP !ATTRAPER LA TEMPERATURE DU NOEUD EN A
*GET, TBMEF, NODE, LabNB, TEMP !ATTRAPER LA TEMPERATURE DU NOEUD EN B

22
NF04 – UTC
Job : post-traitement des bilans – 5.2
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! BILAN DES FLUX !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!
nsel,,loc,X !SELECTION DES NOEUDS DU PLAN X=0
FSUM !SOMMATION DES FLUX NODAUX
*GET, CXM, FSUM, 0, ITEM, HEAT !ATTRAPER LA SOMME DES FLUX NODAUX PRECEDENTE
!!
nsel,,loc,Y,b !SELECTION DES NOEUDS DU PLAN Y=b
nsel,u,loc,X !UNSELECT DES NOEUDS DU PLAN X=0
FSUM
*GET, CYP, FSUM, 0, ITEM, HEAT
!!
nsel,,loc,Y
nsel,u,loc,X
FSUM
*GET, CYM, FSUM, 0, ITEM, HEAT
!!
nsel,all !SELECTION DE TOUS LES NOEUDS
FSUM
*GET, PHITOT, FSUM, 0, ITEM, HEAT !FLUX TOTAL DE REACTION

23
NF04 – UTC
Job : sortie des bilans dans un fichier – 6
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! SORTIE FICHIER !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/OUTPUT,rapport_NF04-1,post,,APPEND !DIRIGER LA SORTIE TEXTE VERS LE FICHIER .post
/COM
/COM JOB=%NOMJOB%
/COM !!!!!!!!!!!!!!!!!!!
/COM !! MODELE !!
/COM !!!!!!!!!!!!!!!!!!!
/COM NB NOEUDS=%NN%
/COM NB ELEM=%NE%
!!!! !**
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! TEMPERATURES !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM ERA=%TAMEF% !**
/COM ERB=%TBMEF% !**
/COM !!!!!!!!!!
/COM !! FLUX !!
/COM !!!!!!!!!!
/COM FLUX Y+=%CYP% mW !**
/COM FLUX X-=%CXM% mW !**
/COM FLUX Y-=%CYM% mW !**
/COM
/OUTPUT !REDIRIGER LA SORTIE TEXTE VERS L’OUTPUT WINDOW

24
NF04 – UTC
Champ de température

25
NF04 – UTC
Forces de réaction sur un maillage raffiné

26
NF04 – UTC
Densité de flux de conduction thermique

27
NF04 – UTC
Densité de flux de conduction thermique : très raffiné

Problème
physique ?

28
NF04 – UTC
TD 1 : cylindre en conduction

FZ+

FRadial?

FZ-

29
NF04 – UTC
Erreurs à ne pas faire !
Savoir présenter des résultats physiques
-Courbes discrètes

-Chiffres significatifs

Savoir rendre un rapport

-Introduction + conclusions
-Livrer dans le délai imparti suivant la procédure 30
NF04 – UTC
II°) TD2 : poutre en flexion

31
NF04 – UTC
Physique du problème

Mécanique des structures minces

-Milieux curvilignes : efforts modélisés par des torseurs (MQ01)
-Grandeurs à analyser : U et ROT (mm et °), sij (MPa), RF et RM (N et Nmm)

=> graphiques : iso-contours et diagrammes de cohésion

=> feuille de calcul : bilan des efforts, flèche max, s max…

32
NF04 – UTC
Physique du problème

3 cas
-CAS 2 : encastré-libre + effort tranchant FZ à l’extrémité libre
-CAS 2’ : encastré-libre + effort tranchant FY à l’extrémité libre
-CAS 4 : appuyé à ses deux extrémités + effort tranchant FZ au centre 33
NF04 – UTC
Orientation d’une section d’élément 188 aligné avec Z

Dans le plan (X,Y) Zloc=Xloc^Yloc

si Xloc n’est pas
colinéaire à Y
Zloc
Yloc
Xloc

Vue d’une section par SECPLOT

= sens contraire de Xloc

34
NF04 – UTC
Théorie : cinématique d’une poutre droite épaisse ?
y

35
NF04 – UTC
Torseur de cohésion ?
y

G
N M 
  x
Ty Mfy 
Tz Mfz 
 G 36
NF04 – UTC
Cinématique et torseur de cohésion d’une section dans le plan
y

G
N 0 
 
Ty 0 
 0 Mfz 
 G HPP = « zoom x100 » au moins
37
NF04 – UTC
Job : paramètres – 1
!! SYSTEME mm, N
!*******************************************************************************
!!PROBLEME
L=5000. !LONGUEUR POUTRE EN mm
FEXT=10000. !N (1T ici)
!!GEOMETRIE DE LA SECTION
W1=100. !LARGEUR SEMELLES
W2=W1
W3=200. !HAUTEUR AME
t1=3. !EPAISSEUR
t2=t1
t3=t1
!!MATERIAU
Young=190000. !MPa
NU=0.3
!!MAILLAGE
NBELEM=2 !NOMBRE ELEMENTS PAIR POUR POINT C
!!POST
NOMJOB='NF04_ANSYS-2'
CAS='4’ !**

38
NF04 – UTC
Job : mise en donnée – 2
!*******************************************************************************
!TITRE SUR LA FENETRE D'AFFICHAGE
/TITLE,%NOMJOB%_CAS%CAS%
/FILENAME,%NOMJOB%_CAS%CAS% !NOM DES FICHIERS GENERES
!*
!*
!*
!*
!*
!*
!*******************************************************************************
/PREP7 !ENTREE DANS LE PREPROCESSEUR
!*
!!POUTRE !TYPE D'EF AVEC L'ORDRE, ICI BILINEAIRE
ET,1,188
KEYOPT,1,3,2 !FORMULATION ISOPARAM(0) OU SUPERPARAM (2)
KEYOPT,1,7,1 !SMAX AUX POINTS D'INTEGRATION
!*
!*
MP,EX,1,YOUNG !MATERIAU
MP,NUXY,1,nu !MATERIAU
!*
!*
K,1,0.0.,0 !CAO : KEYPOINT 1
K,2,L,0.,0. !CAO : KEYPOINT 2
L,1,2 !CAO : LIGNE DE 1->2
lplot 39
NF04 – UTC
Job : définition des sections et maillage – 3
!*MAILLAGE
!
!ASSIGNER LES SECTIONS AUX KEYPOINTS 1 ET 2
SECTYPE,1,BEAM,I !**
SECDATA,W1,W2,W3,t1,t2,t3 !**
!!
SECTYPE,10,TAPER !TAPERED BEAM
SECDATA,1,0.,0.,0. !STARTING LOCATION OF TAPERED BEAM
SECDATA,1,L.,0.,0. !ENDING LOCATION OF TAPERED BEAM
!!
!!
!!
TYPE,1 $MAT,1 $SECNUM,10 !ACTIVER TYPE 1, MAT 1 ET SECTION 10
LESIZE, 1, L/NBELEM, !L/NBELEM=TAILLE DE MAILLE
lmesh,all !MAILLER TOUTES LES LIGNES SELECTIONNEES
!!!!!!!!!!!!

40
NF04 – UTC
Job : CL, chargement et résolution – 4
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Inverser la video!
/RGB,INDEX,100,100,100, 0
/RGB,INDEX, 80, 80, 80,13
/RGB,INDEX, 60, 60, 60,14
/RGB,INDEX, 0, 0, 0,15
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Definir une vue sympa (à partir du sessions editor)
/USER, 1
/VIEW, 1, 0.565040617968 , -0.611926071170 , 0.553421704913
/ANG, 1, -61.6518891670
/REPLO
/AUTO,1
/REP,FAST
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/eshape,1,1 !AFFICHER LA POUTRE AVEC SA GEOMETRIE 3D
/SHOW,PNG,,0 !DEBUT CAPTURES D'ECRAN
secplot,1 !AFFICHER LA SECTION 1
eplot !AFFICHER LES ELEMENTS
/SHOW,CLOSE !FIN CAPTURES D'ECRAN

41
NF04 – UTC
Job : CL, chargement et résolution – 5
!*******************************************************************************
/SOL !ENTREE DANS LE SOLVEUR
!*
ANTYPE,0 !ANALYSE REGIME PERMANENT 0=STATIC
!*
!****************************
!** CL+CHARGEMENT **
!****************************
NSEL,,LOC,X !CL !**
D,ALL,UX !**
D,ALL,UY !**
D,ALL,UZ !**
D,ALL,ROTX !**
!!
NSEL,,LOC,X,L !CL !**
D,ALL,ROTZ !**
D,ALL,UZ !**
!!
NSEL,,LOC,X,L/2 !CHARGEMENT = FORCE CONCENTREE !**
F,ALL,FZ,FEXT !**
!*******************
!*
!*
!*
allsel !TOUT SELECTIONNER
solve !LANCER LE CALCUL SUR LA SELECTION
42
NF04 – UTC
Job : affichage des CL et chargements – 6
!*******************************************************************************
/POST1 !ENTREE DANS LE POSTPROCESSEUR
!
!
!
!
/eshape,1,1 !AFFICHER LA POUTRE AVEC SA GEOMETRIE 3D
!
!
!
/PBC,U,,1 !AFFICHER CL+CHARGEMENTS
/PBC,ROT,,1
/PBC,FORCE,,1
/PBC,MOMENT,,1

43
NF04 – UTC
Job : générer les diagrammes de cohésion – 7
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! TORSEUR DE COHESION !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!ECRITURE DES TABLES aux noeuds I et J DE CHACUN DES EF
!N
ETABLE,FX_I,SMISC,1
ETABLE,FX_J,SMISC,14
!FY
ETABLE,FY_I,SMISC,6
ETABLE,FY_J,SMISC,19
!FZ
ETABLE,FZ_I,SMISC,5
ETABLE,FZ_J,SMISC,18
!M
ETABLE,MX_I,SMISC,4
ETABLE,MX_J,SMISC,17
!MFY
ETABLE,MY_I,SMISC,2
ETABLE,MY_J,SMISC,15
!MFZ
ETABLE,MZ_I,SMISC,3
ETABLE,MZ_J,SMISC,16 -Utilisation des
tables : définition
des SMISC et NMISC dans la librairie
d’éléments (help,188 ici).
-Afficher une table :
PRETAB,NOM_TABLE
44
NF04 – UTC
Job : post-traitement des diagrammes de cohésion – 8
!!ISO-CONTOUR DES COMPOSANTES DU TORSEUR DE COHESION EN REPERE LOCAL DE LA POUTRE
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Definir une vue sympa (à partir du sessions editor)
/VIEW,1,,,1
/ANG,1
/REP,FAST
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/SHOW,PNG,,0 !DEBUT CAPTURES D'ECRAN
/TITLE,%NOMJOB%_CAS%CAS%_N
PLLS,FX_I,FX_J,1. !1.=FACTEUR DE ZOOM
/TITLE,%NOMJOB%_CAS%CAS%_FY
PLLS,FY_I,FY_J,1.
/TITLE,%NOMJOB%_CAS%CAS%_FZ
PLLS,FZ_I,FZ_J,1.
/TITLE,%NOMJOB%_CAS%CAS%_M
PLLS,MX_I,MX_J,1.
/TITLE,%NOMJOB%_CAS%CAS%_MFY
PLLS,MY_I,MY_J,1.
/TITLE,%NOMJOB%_CAS%CAS%_MFZ
PLLS,MZ_I,MZ_J,1.
/SHOW,CLOSE !FIN CAPTURES D'ECRAN
/TITLE,%NOMJOB%_CAS%CAS%

45
NF04 – UTC
Job : post-traitement graphique – 9
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Definir une vue sympa (à partir du sessions editor)
/USER, 1
/VIEW, 1, 0.565040617968 , -0.611926071170 , 0.553421704913
/ANG, 1, -61.6518891670
/REPLO
/AUTO,1
/REP,FAST
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! ISO-CONTOURS !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/GRAPHICS,POWER !MODE POWERGRAPHICS POUR SECTION 3D
/SHOW,PNG,,0 !DEBUT CAPTURES D'ECRAN
ples,s,eqv !VON MISES AUX ELEMENTS
ples,s,x !SXX AUX ELEMENTS
plns,u,sum !NORME DE U AUX NOEUDS
/SHOW,CLOSE !FIN CAPTURES D'ECRAN

46
NF04 – UTC
Job : calcul des erreurs sur la flèche et la contrainte – 10
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! DONNES MODELE !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ALLSEL
*GET, NN, NODE, 0, COUNT !ATTRAPER LE NOMBRE DE NOEUDS
*GET, NE, ELEM, 0, COUNT !ATTRAPER LE NOMBRE D'ELEMENTS
!*
!*
!*
!!!!!!!!!!!!!!!!!!!!!!!!!
!! FLECHE MAX !!
!!!!!!!!!!!!!!!!!!!!!!!!!
LabNB=NODE(L/2,0.,0.) !ATTRAPER LE LABEL DU NOEUD EN B !**
*GET, FLEMEF, NODE, LabNB, UZ !ATTRAPER LA FLECHE NUMERIQUE DU NOEUD C !**
!!
*GET, IYY, SECP, 1, PROP, IYY !INERTIE DE LA SECTION 1 !**
RIGI=YOUNG*IYY
!**
FLEANA=(FEXT*L*L*L)/(48*RIGI) !FLECHE ANALYTIQUE !**
!
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! CONTRAINTE XX MAX !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
*GET,SIGMEF,SECR,ALL,S,X,MAX !PLUS GRANDE CONTRAINTE XX DU MODELE
!!
SIGANA=(FEXT*L/4)/IYY*W3/2. !SXX ANALYTIQUE !**
47
NF04 – UTC
Job : sorties dans un fichier – 11
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! SORTIE FICHIER !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/NOPR
/OUTPUT,rapport_NF04-2,post,,APPEND
/COM JOB=%NOMJOB%_CAS%CAS%
/COM !!!!!!!!!!!!!!!!!!!
/COM !! MODELE !!
/COM !!!!!!!!!!!!!!!!!!!
/COM NB NOEUDS=%NN%
/COM NB ELEM=%NE%
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! FLECHE MAX !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM FLECHE MAX = %FLEMEF%mm
/COM ERFLECHE=%(FLEMEF-FLEANA)/FLEANA*100%%
/COM !!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! SIGMA MAX !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!
/COM SIGMAXX MAX = %SIGMEF% MPa
/COM ERSIGMA=%(SIGMEF-SIGANA)/SIGANA*100%%
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! BILAN DES EFFORTS !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
prrs !SORTIR LES REACTIONS NODALES CALCULEES

48
NF04 – UTC
Job : sorties dans un fichier – 12
/COM
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! DEPLACEMENTS !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
PRNSOL,DOF !SORTIR LES INCONNUES NODALES CALCULEES
/COM
/COM ***************************************************************************
/COM ***************************************************************************
/OUTPUT
!
!
!
!
!
!!!!!!!!!!!!!!!!!!!!!!!!!!
!! RANGER LES RESULTATS !!
!!!!!!!!!!!!!!!!!!!!!!!!!!
/SYS,MKDIR 1RESULTATS
/SYS,MOVE *.PNG 1RESULTATS/
SAVE

49
NF04 – UTC
Torseur de cohésion – cas 4

N M 
 
Ty Mfy 
Tz Mfz 
 G

0 0 
 
 0 Mfy 
Tz 
 0 G
50
NF04 – UTC
Différents cas pour le TD 2

Inertie d’une section ?

Elancement d’une poutre ?

51
NF04 – UTC
Inerties principales de la section en I + élancement l

52
NF04 – UTC
Résolution analytique : flowchart

Notion de déformation : Diagramme de cohésion :

faire apparaître le équilibre d’une section
déplacement recherché (MQ01)

Loi de comportement : équation

différentielle du problème

CL et chargements :
intégration de la solution

53
NF04 – UTC
Résolution analytique : cas 3 = flexion PURE

54
NF04 – UTC
Résolution analytique : cas 3 = flexion PURE
Flèche max ?

Contrainte max ?

55
NF04 – UTC
Résolution analytique : cas 4 = flexion SIMPLE

𝑦 𝑥
𝐹𝑧
 Bilan des forces :
o Tz=Fz/2 pour 0<x<L/2 et Tz=- Fz/2 pour L/2<x<L
o N=Ty=0
𝑥∗𝐹𝑧 𝐿 𝐹𝑧 L
o 𝑀𝑓𝑦 = 𝑝𝑜𝑢𝑟 0 < 𝑥 < 𝑒𝑡 𝑀𝑓𝑦 = L−x pour < 𝑥 < 𝐿
2 2 2 2
o M =Mfz=0.
 Diagrammes de cohésion :
𝑇𝑧 𝑀𝑓𝑦
LFz/4

Fz/2

L/2 L L
0 𝑥 0 𝑥
L/2
-Fz/2

56
NF04 – UTC
Résolution analytique : cas 4 = flexion SIMPLE
 Solution de la flèche maximale analytique :
𝑙
Pour 0 < 𝑥 <
2
𝑥²𝐹𝑧 𝑥 3 𝐹𝑧
𝐸𝐼𝐺𝑦 𝑤 ′′ 𝑥 = 𝑀𝑓𝑦 ⇒ 𝐸𝐼𝐺𝑦 𝑤 ′ 𝑥 = + 𝐾1 ⇒ 𝐸𝐼𝐺𝑦 𝑤 𝑥 = + 𝐾1𝑥 + 𝐾2
4 12
L
Pour < 𝑥 < L:
2
𝐹𝑧 𝑥2
𝐸𝐼𝐺𝑦 𝑤 ′′ 𝑥 = 𝑀𝑓𝑦 ⇒ 𝐸𝐼𝐺𝑦 𝑤′ 𝑥 = (𝐿𝑥 − ) + 𝐾3
4 2
𝐹𝑧 𝑥 2 𝑥 3
𝐸𝐼𝐺𝑦 𝑤 𝑥 = 𝐿 − + 𝐾3𝑥 + 𝐾4
4 2 6
Conditions:
 𝑑𝑒 𝑙𝑖𝑚𝑖𝑡𝑒 𝑠𝑜𝑖𝑡 𝑤 0 = 𝑤 𝐿 = 0
𝐿 𝐿 𝐿 𝐿
 𝑑𝑒 𝑐𝑜𝑛𝑡𝑖𝑛𝑢𝑖𝑡é 𝑠𝑜𝑖𝑡 𝑤′ = 𝑤′ 𝑒𝑡 𝑤 =𝑤
2 𝑠𝑢𝑟 1 2 𝑠𝑢𝑟 2 2 𝑠𝑢𝑟 1 2 𝑠𝑢𝑟 2

Soit après calculs :

3𝐿²𝐹𝑧 9𝐿²𝐹𝑧 𝐿3 𝐹𝑧
𝐾1 = 𝑒𝑡 𝐾2 = 0 𝑒𝑡 𝐾3 = 𝑒𝑡 𝐾4 = −
48 48 48

𝐿 𝐿3 𝐹𝑧
𝐴𝑙𝑜𝑟𝑠 𝐹𝑙𝑒𝑐ℎ𝑒 𝑚𝑎𝑥 = 𝑤 =
2 48𝐸𝐼𝐺𝑦
 Solution de la contrainte normale maximale analytique :
𝑀𝑓𝑚𝑎𝑥 𝑤3 𝐹𝑧 ∗ 𝐿 𝑤3
𝜎𝑚𝑎𝑥 = 𝑧 𝑚𝑎𝑥 𝑎𝑣𝑒𝑐 𝑧 𝑚𝑎𝑥 = 𝑠𝑜𝑖𝑡 𝜎𝑚𝑎𝑥 = 57
𝐼𝐺𝑦 2 4𝐼𝐺𝑦 2
NF04 – UTC
Von Misès – cas 4

CL supplémentaires
pour assurer
l’isostatisme

58
NF04 – UTC
Contrainte normale – cas 4
sxx 0 sxz 
s   0 0 0 
X,Y,Z
 sxz 0 0 

59
NF04 – UTC
Flèche – cas 4

Formulation superparamétrique

f TOT  f CT  f FLEX

3
1 FL
f MAX
FLEX 
48 EI yy

60
NF04 – UTC
Contrainte de cisaillement transverse – cas 4
sxx 0 sxz 
s   0 0 0 
X,Y,Z
 sxz 0 0 

Cisaillement transverse
=> section réduite pour
les efforts tranchants

61
NF04 – UTC
Flèche totale d’une poutre en flexion simple
sxx 0 0  0 0 sxz 
s 
 FLEX X,Y,Z   0 0 0  s 
 CT X,Y,Z   0 0 0 
 0 0 0 sxz 0 0 

f TOT  f CT  f FLEX 62
NF04 – UTC
III°) TD3 : barre en thermoélectricité

63
NF04 – UTC
Physique du problème
TE

VE

TS
Aluminium 
VS

Thermoélectricité des circuits 3D

-Milieux 3D : le courant électrique dissipe de la chaleur par effet joule qui doit
s’échapper de la barre (CL Dirichlet ou Cauchy)
-Grandeurs à analyser : E et i (V/m et A/m²), T et F (°C et W)

=> graphiques : iso-contours, champs de vecteur

=> feuille de calcul : bilan des flux thermique et électrique
64
NF04 – UTC
Système d’unité

Thermique
-[L]=mm
-[T]=°C
-[k]=SI=W°C/m=mW°C/mm
-Les flux sont donc en mW

Electricité
-[L]=mm (choix thermique)
-[P]=[U][I]=mW (choix thermique)
-[U]=mV et [I]=A => [P]=mVA=mW OK
-[R]=[U]/[I]=mV/A=mOhm => [r]=mOhm.mm

Exemple de conversion d’unité

r=30E-9 Ohm.m =30E-9 E3mOhm.E3mm
=30E-3 mOhm.mm

65
NF04 – UTC
Job : paramètres – 1
!! SYSTEME D’UNITES :
! THERMIQUE : mm, °C, mW => cond=mW/mm/°C=W/m/°C=SI
! ELECTRICITE : mm, mV, A => P=UI=mVA=mW, R=U/I=mV/A=mOhm
!
!
!
*****************************************************************************
!!CL
VE=100. !POTENTIEL ENTREE EN mV
VS=0. !POTENTIEL SORTIE EN mV
TE=100. !TEMPERATURE ENTREE EN °C
TS=100. !TEMPERATURE SORTIE EN °C
!!GEOMETRIE
L=1000. !LONGUEUR BARRE EN mm
a=100. !SECTION axb
b=a
!!MATERIAU ALUMINIUM
RES=30E-3 !RESISTIVITE EN mOhm.mm
COND=231 !CONDUCTIVITE EN mW°C/mm
!!MAILLAGE
TM=50 !TAILLE DE MAILLE en mm
!!POST
NOMJOB='NF04_ANSYS-3'
CAS='1'

66
NF04 – UTC
Job : mise en donnée – 2
!*******************************************************************************
!TITRE SUR LA FENETRE D'AFFICHAGE
/TITLE,%NOMJOB%_CAS%CAS%
/FILENAME,%NOMJOB%_CAS%CAS% !NOM DES FICHIERS GENERES
!*
!*
!*
!*******************************************************************************
/PREP7 !ENTREE DANS LE PREPROCESSEUR
!*
!!BARRE 3D
ET,1,69 !H8 THERMOELECTRIQUE
R,1
!*
!*
MP,KXX,1,COND !MATERIAU
MP,RSVX,1,RES !MATERIAU
!*
!*
BLOCK,0,L,-a/2,a/2,-b/2,b/2 !CAO
!*
!*
!*
!*MAILLAGE
AESIZE, ALL, TM !TAILLE DE MAILLE TM SUR TOUTES LES SURFACES
TYPE,1 $MAT,1 $REAL,1 !ACTIVER TYPE 1, MAT 1 ET REAL 1
VMESH,all !MAILLER VOLUME 67
NF04 – UTC
Job : CL, chargement et résolution – 3
!*******************************************************************************
/SOL !ENTREE DANS LE SOLVEUR
!*
ANTYPE,0 !ANALYSE REGIME PERMANENT 0=STATIC
!*
tunif,20
tref,20
toffst,273.15
!*********************************************
!** CL+CHARGEMENT ELECTRIQUE **
!*********************************************
NSEL,,LOC,X !CL
D,ALL,VOLT,VE
NSEL,,LOC,X,L !CL
D,ALL,VOLT,VS
!********************************************
!** CL+CHARGEMENT THERMIQE **
!********************************************
NSEL,,LOC,X !CL
D,ALL,TEMP,TE
NSEL,,LOC,X,L !CL
D,ALL,TEMP,TS
!*******************
!*
!*
allsel !TOUT SELECTIONNER
solve !LANCER LE CALCUL LA SELECTION 68
NF04 – UTC
Job : afficher CL + post-traitement graphique – 4
/POST1 !ENTREE DANS LE POSTPROCESSEUR
!*
!*
!*
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! CL+CHARGEMENTS !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/SHOW,PNG,,0 !DEBUT CAPTURES D'ECRAN
/PBC,VOLT,,1
/PBC,TEMP,,1
eplot
/PBC,VOLT,,0
/PBC,TEMP,,0
/SHOW,CLOSE !FIN CAPTURES D'ECRAN
!*
!*
!*
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! CHAMPS DE VECTEURS !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/SHOW,PNG,,0 !DEBUT CAPTURES D'ECRAN
PLVECT,EF, , , ,VECT,ELEM,ON,0 !champ electrique
PLVECT,JS, , , ,VECT,ELEM,ON,0 !champ d’effet joule
PLVECT,TF, , , ,VECT,ELEM,ON,0 !flux de conduction thermique

69
NF04 – UTC
Job : post-traitement graphique – 5
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! ISO-CONTOURS !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
plns,TEMP !TEMPERATURES NODALES
plns,VOLT !TENSIONS NODALES
/SHOW,CLOSE !FIN CAPTURES D'ECRAN

70
NF04 – UTC
Job : bilans – 6
!!!!!!!!!!!!!!!!!!!!!!
!! BILANS !!
!!!!!!!!!!!!!!!!!!!!!!
!*
!!EFFET JOULE
etable,DENS_JOULE,jheat !TABLE DE DENSITE DE CHALEUR DE JOULE
etable,VOL,volu !TABLE DES VOLUMES ELEMENTAIRES
smult,FLUX_JOULE,DENS_JOULE,VOL !TABLE DES FLUX DE CHALEUR JOULE ELEMENTAIRES
ssum !SOMMER LES FLUX ELEMENTAIRES
*get,JOULE,SSUM,FLUX_JOULE !ATTRAPER LA VALEUR TOTALE DE L'EFFET JOULE
!*
!!REACTIONS AUX CL
NSEL,,LOC,X !SELECTIONNER NOEUDS ENTREE
FSUM !SOMMER LES REACTIONS
*get,FLUX_E,FSUM,,ITEM,heat !ATTRAPER LA VALEUR TOTALE DU FLUX DE CONDUCTION
*get,INT_E,FSUM,,ITEM,amps !ATTRAPER LA VALEUR TOTALE DE L'INTENSITE
!!
NSEL,,LOC,X,L !SELECTIONNER NOEUDS SORTIE
FSUM !SOMMER LES REACTIONS
*get,FLUX_S,FSUM,,ITEM,heat !ATTRAPER LA VALEUR TOTALE DU FLUX DE CONDUCTION
*get,INT_S,FSUM,,ITEM,amps !ATTRAPER LA VALEUR TOTALE DE L'INTENSITE
!*
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! DONNES MODELE !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ALLSEL
*GET, NN, NODE, 0, COUNT !ATTRAPER LE NOMBRE DE NOEUDS 71
*GET, NE, ELEM, 0, COUNT !ATTRAPER LE NOMBRE D'ELEMENTS
NF04 – UTC
Job : sorties dans un fichier – 7
!*******************************************************************************
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! SORTIE FICHIER !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/NOPR
/OUTPUT,rapport_NF04-3,post,,APPEND
/COM JOB=%NOMJOB%_CAS%CAS%
/COM !!!!!!!!!!!!!!!!!!
/COM !! MODELE !!
/COM !!!!!!!!!!!!!!!!!!
/COM NB NOEUDS=%NN%
/COM NB ELEM=%NE%
/COM ***************************************************************************
/COM TE (°C)= %TE%
/COM TS (°C)= %TS%
/COM VE (mV)= %VE%
/COM VS (mV)= %VS%
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! BILAN !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!
prrs !SORTIR LES REACTIONS NODALES CALCULEES

72
NF04 – UTC
Job : sorties dans un fichier – 8
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! BALANCE EF !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM ***************************************************************************
/COM FLUX THERMIQUE ENTREE (kW) = %FLUX_E*1E-6%
/COM FLUX THERMIQUE SORTIE (kW) = %FLUX_S*1E-6%
/COM DISSIPATION EFFET JOULE (kW) = %JOULE*1E-6%
/COM BALANCE (mW) : %FLUX_E+FLUX_S-JOULE%
/COM INTENSITE ENTREE (kA) = %INT_E*1E-3%
/COM INTENSITE SORTIE (kA) = %INT_S*1E-3%
/COM BALANCE (A) : %INT_E+INT_S%
/COM ***************************************************************************
/COM RESISTANCE TOTALE EF (mOhm) = %(VS-VE)/INT_S%
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM !! EF vs ANA !!
/COM !!!!!!!!!!!!!!!!!!!!!!!!!!!!
/COM RESISTANCE TOTALE ANALYTIQUE (mOhm) =
/COM CHAMP ELECTRIQUE ANALYTIQUE (V/m) =
/COM EFFET JOULE ANALYTIQUE (kW) =
/COM ***************************************************************************
/COM ***************************************************************************
/OUTPUT
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! RANGER LES RESULTATS !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/SYS,MKDIR 1RESULTATS
/SYS,MOVE *.PNG 1RESULTATS/ 73
SAVE
NF04 – UTC
Température – cas 1

TE

TS
CL pour assurer
l’isostatisme

74
NF04 – UTC
Potentiel – cas 1

VE

VS
CL pour assurer
l’isostatisme

75
NF04 – UTC
Champ électrique – cas 1

IRE + IRS = 0

Rcircuit=(VS-VE)/IRS

76
NF04 – UTC
Densité de flux de conduction thermique – cas 1

Fjoule=U²/R

FRE + FRS = Fjoule

77
NF04 – UTC